語法
ISBLANK(value)
ISERR(value)
ISERROR(value)
ISLOGICAL(value)
ISNA(value)
ISNONTEXT(value)
ISNUMBER(value)
ISREF(value)
ISTEXT(value)
Value 為需要進行檢驗的數值。分別為：空白（空白單元格）、錯誤值、邏輯值、文本、數字、引用值或對於以上任意參數的名稱引用。函式如果為下面的內容，則返回 TRUE
ISBLANK 值為空白單元格。
ISERR 值為任意錯誤值（除去 #N/A）。
ISERROR 值為任意錯誤值（#N/A、#VALUE!、#REF!、#DIV/0!、#NUM!、#NAME? 或 #NULL!）。.
ISLOGICAL 值為邏輯值。
ISNA 值為錯誤值 #N/A（值不存在）。
ISNONTEXT 值為任意不是文本的項（注意此函式在值為空白單元格時返回 TRUE）。
ISNUMBER 值為數字。
ISREF 值為引用。
ISTEXT 值為文本。
說明
IS 類函式的參數 value 是不可轉換的。例如，在其他大多數需要數字的函式中，文本值 "19" 會被轉換成數字 19。然而在公式 ISNUMBER("19") 中，"19" 並不由文本值轉換成別的類型的值，函式 ISNUMBER 返回 FALSE。
IS 類函式在用公式檢驗計算結果時十分有用。當它與函式 IF 結合在一起使用時，可以提供一種方法用來在公式中查出錯誤值（請參閱下面的示例）。
示例
ISLOGICAL(TRUE) 等於 TRUE
ISLOGICAL("TRUE") 等於 FALSE
ISNUMBER(4) 等於 TRUE
假設在有關黃金價格的工作表中 C1:C5 的不同區域分別顯示出下面的文本值、數字和錯誤值："Gold"、"Region1"、#REF!、$330.92、#N/A。
ISBLANK(C1) 等於 FALSE
ISERROR(C3) 等於 TRUE
ISNA(C3) 等於 FALSE
ISNA(C5) 等於 TRUE
ISERR(C5) 等於 FALSE
ISNUMBER(C4) 等於 TRUE（如果 $330.92 作為數字輸入而不是作為文本輸入）
ISREF(Region1) 等於 TRUE（如果 Region1 定義為區域名）
ISTEXT(C2) 等於 TRUE（如果 Region1 的格式為文本）
在另一個工作表中，假設需要計算 A1:A4 區域的平均值，但不能確定單元格內是否包含數字。如果 A1:A4 不包含任何數字，公式 AVERAGE(A1:A4) 返回錯誤值 #DIV/0!。為了應付這種情況，可以使用下面的公式來查出潛在的錯誤值：
IF(ISERROR(AVERAGE(A1:A4)),"No Numbers",AVERAGE(A1:A4))
