buttoncount 屬性
指定命令組或選項組中的按鈕數。
語法
Control.ButtonCount[ = nNumber]
設定
nNumber
指定按鈕數目。
說明
設計和運行時可用。
使用 buttoncount 屬性來動態設定包含於命令組或選項組中的按鈕數。
如果在運行時更改按鈕數，則自動給新按鈕命名。命令組中按鈕被命名為 CommandN，選項組中按鈕被命名為 OptionN，其中 N 為所添加的按鈕數。例如，如果命令組中有四個按鈕而 ButtonCount 屬性設定更改為 5，則新按鈕命名為 Command5。
buttoncount 屬性示例
下例創建一個選項組控制並將該控制放置在表單中。選項組控制有三個按鈕，根據用戶單擊的選項按鈕，顯示一個圓、橢圓或正方形。buttoncount 屬性用於指定選項組中的按鈕數。buttons 和 caption 屬性用於指定顯示在每一選項按鈕旁的文本。
形狀控制用於創建圓、橢圓和正方形。選項組控制的 click 事件採用 do case…endcase 結構，並在用戶單擊一個選項按鈕時，value 屬性顯示相應的形狀。
frmmyform = createobject('form') && 創建一個表單
frmmyform.closable = .f. && 廢止“控制”選單框
frmmyform.addobject('cmdcommand1','cmdmycmndbtn') && 添加命令按鈕
frmmyform.addobject('opgoptiongroup1','opgmyoptgrp') && 添加“選擇”按鈕
frmmyform.addobject('shpcircle1','shpmycircle') && 添加“圓”形狀控制
frmmyform.addobject('shpellipse1','shpmyellipse') && 添加“橢圓”形狀控制
frmmyform.addobject('shpsquare','shpmysquare') && 添加“框”形狀控制
frmmyform.cmdcommand1.visible =.t. && “退出”命令按鈕可視
frmmyform.opgoptiongroup1.buttons(1).caption = "\<circle"
frmmyform.opgoptiongroup1.buttons(2).caption = "\<ellipse"
frmmyform.opgoptiongroup1.buttons(3).caption = "\<square"
frmmyform.opgoptiongroup1.setall("width", 100) && 設定選項組寬度
frmmyform.opgoptiongroup1.visible = .t. && 設定選項組可見
frmmyform.opgoptiongroup1.click && 顯示圓
frmmyform.show && 顯示錶單
read events && 開始事件處理
define class opgmyoptgrp as optiongroup && 建立選項組
buttoncount = 3 && 三個選項按鈕
top = 10
left = 10
height = 75
width = 100
procedure click
thisform.shpcircle1.visible = .f. && 隱藏圓
thisform.shpellipse1.visible = .f. && 隱藏橢圓
thisform.shpsquare.visible = .f. && 隱藏正方形
do case
case thisform.opgoptiongroup1.value = 1
thisform.shpcircle1.visible = .t. && 顯示圓
case thisform.opgoptiongroup1.value = 2
thisform.shpellipse1.visible = .t. && 顯示橢圓
case thisform.opgoptiongroup1.value = 3
thisform.shpsquare.visible = .t. && 顯示正方形
endcase
enddefine
define class cmdmycmndbtn as CommandButton && 創建命令按鈕
caption = '\<quit' && 在命令按鈕上的標題
cancel = .t. && 默認“取消”命令按鈕 (esc)
left = 125 && 命令按鈕列
top = 210 && 命令按鈕行
height = 25 && 命令按鈕高度
procedure click
clear events && 終止事件處理，關閉表單
enddefine
define class shpmycircle as shape && 創建一個圓
top = 10
left = 200
width = 100
height = 100
curvature = 99
backcolor = rgb(255,0,0) && 紅色
enddefine
define class shpmyellipse as shape && 創建一個橢圓
top = 35
left = 200
width = 100
height = 50
curvature = 99
backcolor = rgb(0,128,0) && 綠色
enddefine
define class shpmysquare as shape && 創建一個正方形
top = 10
left = 200
width = 100
height = 100
curvature = 0
backcolor = rgb(0,0,255) && 藍色
enddefine
套用於
commandgroup, optiongroup
