backcolor, forecolor 屬性
指定用於顯示對象中文本和圖形的背景色或前景色。設計和運行時可用。
語法
Object.BackColor[ = nColor]
Object.ForeColor[ = nColor]
設定
nColor
指定單個顏色值。下表列出常用的顏色值：
顏色 RGB 值 nColor 值
白色 255, 255, 255 16777215
黑色 0, 0, 0 0
灰色 192, 192, 192 12632256
暗灰色 128, 128, 128 8421504
紅色 255, 0, 0 255
暗紅色 128, 0, 0 128
黃色 255, 255, 0 65535
暗黃色 128, 128, 0 32896
綠色 0, 255, 0 65280
暗綠色 0, 128, 0 32768
青色 0, 255, 255 16776960
暗青色 0, 128, 128 8421376
藍色 0, 0, 255 16711680
暗藍色 0, 0, 128 8388608
洋紅色 255, 0 ,255 16711935
暗洋紅色 128, 0, 128 8388736
說明
Visual FoxPro 採用 Windows 紅綠藍 (RGB) 配色方案，每一個紅、綠、藍組件由一個 0 到 255 之間的值代表。使用 RGB( ) 函式將三個組件顏色轉換為一個複合的 nColor。
若 backstyle 屬性設定為 0(透明)，則忽略 BackColor 屬性。
backcolor, forecolor 屬性示例
下面示例演示了如何在表單中使用 shape 控制顯示圓、橢圓或正方形，以及怎樣用 backcolor 屬性來指定每一形狀的顏色。
創建一個表單，並且將一個命令按鈕和一組選項按鈕放置在表單上。當選擇某一選項按鈕時，表單上將顯示相應的形狀。 backcolor 屬性可用於指定每一形狀的顏色。每一形狀的 height、 width 和 curvature 屬性決定其類型。
frmmyform = createobject('form') && 創建一個表單
frmmyform.closable = .f. && 使控制選單框無效
frmmyform.addobject('cmdcommand1','cmdmycmndbtn') && 添加命令按鈕
frmmyform.addobject('opgoptiongroup1','opgmyoptgrp') && 添加選項組
frmmyform.addobject('shpcircle1','shpmycircle') && 添加圓
frmmyform.addobject('shpellipse1','shpmyellipse') && 添加橢圓
frmmyform.addobject('shpsquare','shpmysquare') && 添加框
frmmyform.cmdcommand1.visible =.t. && "退出"命令按鈕可見
frmmyform.opgoptiongroup1.buttons(1).caption = "\<circle"
frmmyform.opgoptiongroup1.buttons(2).caption = "\<ellipse"
frmmyform.opgoptiongroup1.buttons(3).caption = "\<square"
frmmyform.opgoptiongroup1.setall("width", 100) && 設定選項組寬度
frmmyform.opgoptiongroup1.visible = .t. && 選項組可見
frmmyform.opgoptiongroup1.click && 顯示圓
frmmyform.show && 顯示錶單
read events && 啟動事件處理
define class opgmyoptgrp as optiongroup && 創建一個選項組
buttoncount = 3 && 三個選項按鈕
top = 10
left = 10
height = 75
width = 100
procedure click
thisform.shpcircle1.visible = .f. && 隱藏圓
thisform.shpellipse1.visible = .f. && 隱藏橢圓
thisform.shpsquare.visible = .f. && 隱藏正方形
do case
case thisform.opgoptiongroup1.value = 1
thisform.shpcircle1.visible = .t. && 顯示圓
case thisform.opgoptiongroup1.value = 2
thisform.shpellipse1.visible = .t. && 顯示橢圓
case thisform.opgoptiongroup1.value = 3
thisform.shpsquare.visible = .t. && 顯示正方形
endcase
enddefine
define class cmdmycmndbtn as CommandButton && 創建命令按鈕
caption = '\<quit' && 命令按鈕上的標題
cancel = .t. && 默認取消命令按鈕 (esc)
left = 125 && 命令按鈕列
top = 210 && 命令按鈕行
height = 25 && 命令按鈕高度
procedure click
clear events && 停止事件處理，關閉表單
enddefine
define class shpmycircle as shape && 創建一個圓
top = 10
left = 200
width = 100
height = 100
curvature = 99
backcolor = rgb(255,0,0) && 紅色
enddefine
define class shpmyellipse as shape && 創建一個橢圓
top = 35
left = 200
width = 100
height = 50
curvature = 99
backcolor = rgb(0,128,0) && 綠色
enddefine
define class shpmysquare as shape && 創建一個正方形
top = 10
left = 200
width = 100
height = 100
curvature = 0
backcolor = rgb(0,0,255) && 藍色
enddefine
套用於
checkbox, column, combobox, commandbutton, commandgroup, container對象, control對象, editbox, form, grid, header, label, optionbutton, optiongroup, page, _screen, shape, spinner, textbox, toolbar
注意 backcolor 屬性沒有套用於 commandbutton 控制項。 forecolor 屬性沒有套用於 commandgroup, optiongroup, 或 shape 控制項。
