buttons 屬性
訪問一個控制組中每個按鈕的數組。設計時不可用。訪問一個控制組中每個按鈕的數組。設計時不可用。
語法
Control.Buttons (nIndex).Property = Value
— 或者 —
Control.Buttons (nIndex).Method
設定
nIndex
是 1 和 Control 的 buttoncount 屬性所指定的按鈕數之間的一個整數。
Property
命令按鈕或選項按鈕的屬性。
Method
命令按鈕或選項按鈕的方法。
Value
Property 的值。
說明
可使用 buttons 屬性為組內的所有按鈕設定屬性和調用方法。buttons 屬性是在創建按鈕組時創建的一個數組。
Buttons 屬性示例
下例創建一個選項組控制並在一個表單上設定該控制。選項組有三個按鈕，根據用戶單擊的選項按鈕，顯示一個圓、橢圓或正方形。ButtonCount 屬性用於指定選項組的按鈕數，Buttons 和 Caption 屬性用於指定顯示在每一選項按鈕旁的文本。
形狀控制用於創建圓、橢圓和正方形。選項組控制的 Click 事件採用 DO CASE ... ENDCASE 結構，並在用戶單擊一個選項按鈕時，Value 屬性顯示相應的形狀。
frmMyForm = CREATEOBJECT('Form') && 創建一個表單
frmMyForm.Closable = .F. && 廢止“控制”選單框
frmMyForm.AddObject('cmdCommand1','cmdMyCmndBtn') && 添加命令按鈕
frmMyForm.AddObject('opgOptionGroup1','opgMyOptGrp') && 添加選項組
frmMyForm.AddObject('shpCircle1','shpMyCircle') && 添加圓
frmMyForm.AddObject('shpEllipse1','shpMyEllipse') && 添加橢圓
frmMyForm.AddObject('shpSquare','shpMySquare') && 添加框
frmMyForm.cmdCommand1.Visible =.T. && “退出”命令按鈕可視
frmMyForm.opgOptionGroup1.Buttons(1).Caption = "\<Circle"
frmMyForm.opgOptionGroup1.Buttons(2).Caption = "\<Ellipse"
frmMyForm.opgOptionGroup1.Buttons(3).Caption = "\<Square"
frmMyForm.opgOptionGroup1.SetAll("Width", 100) && 設定選項組寬度
frmMyForm.opgOptionGroup1.Visible = .T. && 選項組可見
frmMyForm.opgOptionGroup1.Click && 顯示圓
frmMyForm.SHOW && 顯示錶單
READ EVENTS && 啟動事件處理
DEFINE CLASS opgMyOptGrp AS OptionGroup && 創建一個選項組
ButtonCount = 3 && 三個選擇按鈕
Top = 10
Left = 10
Height = 75
Width = 100
PROCEDURE Click
ThisForm.shpCircle1.Visible = .F. && 隱藏圓
ThisForm.shpEllipse1.Visible = .F. && 隱藏橢圓
ThisForm.shpSquare.Visible = .F. && 隱藏正方形
DO CASE
CASE ThisForm.opgOptionGroup1.Value = 1
ThisForm.shpCircle1.Visible = .T. && 顯示圓
CASE ThisForm.opgOptionGroup1.Value = 2
ThisForm.shpEllipse1.Visible = .T. && 顯示橢圓
CASE ThisForm.opgOptionGroup1.Value = 3
ThisForm.shpSquare.Visible = .T. && 顯示正方形
ENDCASE
ENDDEFINE
DEFINE CLASS cmdMyCmndBtn AS CommandButton && 創建命令按鈕
Caption = '\<Quit' && 命令按鈕上的標題
Cancel = .T. && 默認“取消”命令按鈕 (Esc)
Left = 125 && 命令按鈕列
Top = 210 && 命令按鈕行
Height = 25 && 命令按鈕高度
PROCEDURE Click
CLEAR EVENTS && 終止事件處理，關閉表單
ENDDEFINE
DEFINE CLASS shpMyCircle AS SHAPE && 創建一個圓
Top = 10
Left = 200
Width = 100
Height = 100
Curvature = 99
BackColor = RGB(255,0,0) && 紅色
ENDDEFINE
DEFINE CLASS shpMyEllipse AS SHAPE && 創建一個橢圓
Top = 35
Left = 200
Width = 100
Height = 50
Curvature = 99
BackColor = RGB(0,128,0) && 綠色
ENDDEFINE
DEFINE CLASS shpMySquare AS SHAPE && 創建一個正方形
Top = 10
Left = 200
Width = 100
Height = 100
Curvature = 0
BackColor = RGB(0,0,255) && 藍色
ENDDEFINE
套用於
commandgroup, optiongroup
